/*
* WATERRIPPLE
*
* WaterRipple tries to mimic the behavior of water. It displays an image that when the mouse is moved over it acts as tho it lies underneath water and a finger is run through the water. The code has been slightly tweaked compared to the original Java-code found the link below. Noted in source-code below.
* 
* To recreate, you'll need to have the Flash9 ActionScript3 Preview installed, you can get it at http://labs.adobe.com/technologies/flash9as3preview/
* Create a new 200x200 FLA, and put 'WaterRipple' (without quotes) as its Document Class. Test Movie et voila!
* 
* @author	Edwin Heijmen
* @version	0.1
* 
* @see	http://www.neilwallis.com/java/water.html
*/

package {
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
    import flash.utils.Timer;
	
	public class WaterRipple extends MovieClip {
		private var imageW:Number; // width
		private var imageH:Number; // height
		private var iW2:Number; // half of width
		private var iH2:Number; // half of height
		private var hArr:Array = new Array(); // height array used for ripple effect
		private var tggl:uint = 0; // used to toggle between current and future states
		private var riprad:uint = 15; // radius used for ripple-distortion

		// used for loading image, displaying fractal and interaction
		private var img:Loader;
		private var bmd:BitmapData;
		private var bm:Bitmap = null;
		private var origData:BitmapData; // bitmapdata of original image
		private var sp:Sprite = new Sprite();

		public function WaterRipple () {
			// constructor
			//
			// first load in picture
			img = new Loader();
			img.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
			var request:URLRequest = new URLRequest("ggoo_200x200.jpg");
			img.load(request);
		}
		
		private function completeHandler (event:Event):void {
			// loading completed, now we can start digging around
			//
			// get width & height
			imageW = img.contentLoaderInfo.width;
			imageH = img.contentLoaderInfo.height;
			iW2 = imageW/2;
			iH2 = imageH/2;
			//
			// create mouselistener
			sp.graphics.beginFill(0xFFFFFF);
			sp.graphics.lineTo(imageW,0);
			sp.graphics.lineTo(imageW,imageH);
			sp.graphics.lineTo(0,imageH);
			sp.graphics.lineTo(0,0);
			sp.graphics.endFill();
			addChild(sp);
			sp.addEventListener("mouseMove",disturb);
			//
			// first make sure we can distort image
			var image:Bitmap = Bitmap(img.content);
			origData = image.bitmapData;
			bmd = origData.clone();
			bm = new Bitmap(bmd);
			addChild(bm);
			//
			// create height arrays
			for (var i:uint=0;i<2;++i) {
				var temp:Array = new Array();
				for (var tX:uint=0;tX<imageW;++tX) {
					var t:Array = new Array();
					for (var tY:uint=0;tY<imageH;++tY) {
						t.push(0);
					}
					temp.push(t);
				}
				hArr.push(temp);
			}
			//
            var myTimer:Timer = new Timer(0);
            myTimer.addEventListener("timer",doUpdate);
            myTimer.start();			
		}
		
		private function disturb (event:Event=null):void {
			// get mouse position and update height array
			//
			var l:uint = Math.max(0,mouseX-riprad);
			var r:uint = Math.min(imageW,mouseX+riprad);
			var t:uint = Math.max(0,mouseY-riprad);
			var b:uint = Math.min(imageH,mouseY+riprad);
			var hT:Array = hArr[tggl]
			for (var i:uint=l;i<r;++i) {
				var hTI:Array = hT[i];
				for (var j:uint=t;j<b;++j) {
					hTI[j] += 1024; // upped from 512
				}
			}
		}
		
		private function doUpdate (event:Event=null):void {
			// calculate and draw the distortion
			//
			// create new bitmap based on old
			var l:uint;
			var t:uint;
			var r:uint;
			var b:uint;
			var d:Number;
			var ii:Number;
			var jj:Number;
			var cHArr:Array = hArr[tggl]; // current height array
			var oHArr:Array = hArr[1-tggl]; // previous height array
			// loop over pixels and fill em using origData & height arrays
			for (var i:Number=0;i<imageW;++i) {
				for (var j:Number=0;j<imageH;++j) {
					// determine coordinate to copy to (i,j), ripples are wrapped around edges
					l = (i>0)?(i-1):(imageW-1);
					r = (i<imageW-1)?(i+1):(0);
					t = (j>0)?(j-1):(imageH-1);
					b = (j<imageH-1)?(j+1):(0);
					// calculate influence of ripples
					d = (oHArr[l][j]+oHArr[r][j]+oHArr[i][t]+oHArr[i][b])/2-cHArr[i][j];
					cHArr[i][j] = d*.9; // not in original code
					d /= 32; // in original code this calue is set in height array instead
					d = (1024-d)/1024;
					// calculate offsets & check bounds
					ii = (i-iW2)*d+iW2;
					if (ii>=imageW) ii = imageW-1;
					else if (ii<0) ii = 0;
					jj = (j-iH2)*d+iH2;
					if (jj>=imageH) jj = imageH-1;
					else if (jj<0) jj = 0;
					bmd.setPixel(i,j,origData.getPixel(ii,jj));
				}
			}
			//
			// update toggle
			tggl = 1-tggl;
		}
		
	}
	
}