/*
* MULTICOLORED CELLULAR AUTOMATA
* 
* Draws a multi-colored one-dimensional Cellular Automata. Each cell can have a range of different states based on its previous state and that of its neighbors, all from the previous generation.
* 
* To recreate, you'll need to have the Flash9 ActionScript3 preview installed, you can get it at http://labs.adobe.com/technologies/flash9as3preview/
* Create a new 600x300 FLA, and put 'MultiColoredCA' (without quotes) as its Document Class. Test Movie et voila!
* 
* @author	Edwin Heijmen
* @version	0.1
*
* @see	http://www.wolframscience.org/
*/

package {
	import flash.display.*;
	import flash.events.*;
	import flash.geom.*;
	import flash.utils.Timer;
	
	public class MultiColoredCA extends MovieClip {
		private var states:Array; // keeps track of states of cells on last-drawn line
		private var w:uint = 600; // width
		private var h:uint = 300; // height
		private var row:Number = 1; // keeps track of which row to draw
		private var rect:Rectangle; // used to copy from previous genereation to current generation
		private var p:Point; // used as referencepoint to copy previous generation to
		
		// settings for determining state
		private var num:uint = 64; // number of states
		private var num4:Number = num/4; // gets added to sum of neighboring states of previous generation
		private var fact:Number = 256/num; // factor to distribute num states evenly across 256 possible colors
		
		// used for displaying purposes
		private var bmd:BitmapData;
		private var bm:Bitmap;
		
		public function MultiColoredCA () {
			// constructor
			//
			// fill states array
			states = new Array();
			for (var i:uint=0;i<h;++i) {
				for (var j:uint=0;j<w;++j) {
					states.push(0);
				}
			}
			// set intial data
			var w2:uint = Math.floor(w/2);
			var o:uint = 2;
			for (j=w2-o;j<w2+o+1;++j) {
				states[j] = num-1;
			}
			//
			// bitmap data
			bmd = new BitmapData(w,h);
			bm = new Bitmap(bmd);
			this.addChild(bm);
			//
			// rectangle area used for copying generations
			rect = new Rectangle(0,1,w,h);
			// point 
			p = new Point(0,0);
			//
			// start executing function
            var myTimer:Timer = new Timer(0);
            myTimer.addEventListener("timer",doNext);
            myTimer.start();
		}
		
		public function doNext (event:Event=null):void {
			// calculate and draw next generation
			//
			// left neighbor in current generation
			var c1:uint;
			// own value in current generation
			var c2:uint;
			// right neighbor in current generation
			var c3:uint;
			// sum of current generation incl weights
			var sum:uint;
			// create array used to store next generation
			var s:Array = new Array();
			// determine row to draw
			var r:uint;
			// do we need to copy rectangle?
			if (h-1<row) {
				// copy rectangle
				bmd.copyPixels(bmd,rect,p);
				// set r
				r = h-1;
			} else r = row;
			// determine new values
			for (j=0;j<w;++j) {
				// get 3 values from current generation (neighbors plus previous)
				c1 = (j>0)?(states[j-1]):(states[w-1]); 
				c2 = states[j];
				c3 = (j<w-1)?(states[j+1]):(states[0]);
				// determine new state based on previous with weights
				sum = Math.floor(((c1+c2+c3+num4)/3)%num);
				//
				s.push(sum);
				bmd.setPixel(j,r,(sum*fact)<<16);
			}
			// copy next generation to current generation
			states = s;
			// update row
			row++;
		}
		
	}
}