/*
* GAME OF LIFE
* 
* Conway's Game Of Life is not a game, but probably the most famous/well-known example of Cellular Automata. It is a simulation of Artificial Life where each cell in a grid can be either dead or alive and these states can switch on each generation based on a couple of simple rules. Also see the links below.
* 
* To recreate, you'll need to have the Flash9 ActionScript3 preview installed, you can get it at http://labs.adobe.com/technologies/flash9as3tggliew/
* Create a new 400x400 FLA, and put 'GameOfLife' (without quotes) as its Document Class. Test Movie et voila!
* 
* @author	Edwin Heijmen
* @version	0.1
*
* @see	http://en.wikipedia.org/wiki/Conway's_Game_of_Life
*/

package {
	import flash.display.*;
	import flash.events.*;
    import flash.utils.Timer;
	
	public class GameOfLife extends MovieClip {
		private var states:Array = new Array(); // keep track of previous and current states
		private var w:uint = 400; // width
		private var h:uint = 400; // height
		private var rnd:Number = 0.15; // random chance of a live cell at start
		private var tggl:uint = 0; // toggle between current and previous states
		private var alive:Number = 0xFF0000;
		private var dead:Number = 0xFFFFFF;

		// used for displaying purposes
		private var bmd:BitmapData;
		private var bm:Bitmap;

		public function GameOfLife () {
			// constructor
			//
			// fill states array, once for current and once for previous
			states[0] = new Array(); // previous
			states[1] = new Array(); // current
			for (var i:uint=0;i<w;++i) {
				states[0][i] = new Array();
				states[1][i] = new Array();
				for (var j:uint=0;j<h;++j) {
					// determine random state
					states[0][i].push((Math.random()<rnd)?(1):(0));
				}
			}
			//
			bmd = new BitmapData(w,h);
			bm = new Bitmap(bmd);
			this.addChild(bm);
			//
			// start executing function
            var myTimer:Timer = new Timer(0);
            myTimer.addEventListener("timer",doNext);
            myTimer.start();
		}
		
		private function doNext (event:Event=null):void {
			// calculates and draws
			//
			// get previous & current
			var pS:Array = states[tggl];
			var cS:Array = states[(1-tggl)];
			var nS:uint;
			var sum:uint;
			var im1:uint;
			var ip1:uint;
			var jm1:uint;
			var jp1:uint;
			var pState:uint;
			// loop over variables and calculate next move
			for (var i:uint=0;i<w;++i) {
				for (var j:uint=0;j<h;++j) {
					// get own state of (i,j)
					pState = pS[i][j];
					// calculate sum of states of neighbors
					im1 = (i-1+w)%w;
					ip1 = (i+1)%w;
					jm1 = (j-1+h)%h;
					jp1 = (j+1)%h;
					sum = pS[im1][jm1]+pS[im1][j]+pS[im1][jp1]+pS[i][jm1]+pS[i][jp1]+pS[ip1][jm1]+pS[ip1][j]+pS[ip1][jp1];
					// determine new state of (i,j)
					if (pState==1&&(sum==2||sum==3)) {
						// cell was alive and can stay alive
						//
						nS = 1;
					} else if (pState==0&&sum==3) {
						// cell was dead but resurrects
						//
						nS = 1;
					} else {
						// cell remains dead or dies
						//
						nS = 0;
					}
					// set new states
					cS[i][j] = nS;
					bmd.setPixel(i,j,(nS==1)?(alive):(dead));
				}
			}
			// update tggl
			tggl = 1-tggl;
		}
	}
	
}